欢迎光临
个人知识库,ERP、IT知识分享和应用

恢复Win11 经典的右键菜单

切换到旧版右键菜单:

reg add "HKCU\Software\Classes\CLSID\{86ca1aa0-34aa-4e8b-a509-50c905bae2a2}\InprocServer32" /f /ve

恢复回Win11右键菜单:

reg delete "HKCU\Software\Classes\CLSID\{86ca1aa0-34aa-4e8b-a509-50c905bae2a2}" /f

重启Windows资源管理器生效。

taskkill /f /im explorer.exe & start explorer.exe
运行命令。右键开始菜单,Windows终端管理员。输入cmd后,然后输入上面的命令就好了
来源: 知彼而知己

以下是另一网友整理的CMD脚本,复制另存为.CMD再运行即可。

@echo off
title Windows 11 新旧右键菜单切换

>NUL 2>&1 REG.exe query "HKU\S-1-5-19" || (
ECHO SET UAC = CreateObject^("Shell.Application"^) > "%TEMP%\Getadmin.vbs"
ECHO UAC.ShellExecute "%~f0", "%1", "", "runas", 1 >> "%TEMP%\Getadmin.vbs"
"%TEMP%\Getadmin.vbs"
DEL /f /q "%TEMP%\Getadmin.vbs" 2>NUL
Exit /b
)

:menu
cls
echo ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
echo ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
echo 欢迎使用落尘之木脚本
echo.
echo 请选择项目: 
echo.&echo 【1】Win11转回旧版右键菜单
echo.&echo 【2】Win11恢复新版右键菜单
echo.&echo 请输入数字回车确认
echo.

set /p user_input=请输入数字:
if %user_input% equ 1 goto old
if %user_input% equ 2 goto new
echo 输入错误, 请重新输入数字.
pause
goto menu

:old
reg add "HKCU\Software\Classes\CLSID\{86ca1aa0-34aa-4e8b-a509-50c905bae2a2}\InprocServer32" /f /ve
taskkill /f /im explorer.exe & start explorer.exe
echo 已成功转到旧版右键菜单
pause
goto menu

:new
reg delete "HKCU\Software\Classes\CLSID\{86ca1aa0-34aa-4e8b-a509-50c905bae2a2}" /f
taskkill /f /im explorer.exe & start explorer.exe
echo 已成功恢复新版右键菜单
pause
goto menu
未经允许不得转载:Blog.XiaoMing.Xyz » 恢复Win11 经典的右键菜单
分享到: 更多 (0)

评论 抢沙发

  • 昵称 (必填)
  • 邮箱 (必填)
  • 网址