欢迎光临
个人知识库,ERP、IT知识分享和应用

完美绕过Win11硬件限制的技术要素

很多人在升级Win11的过程中,遇到了不满足硬件条件的提示。经过这些天的测试,以及收到的各种反馈:

有的人仅仅删除appraiserres.dll,即可绕过Win11硬件检测。有的人删除appraiserres.dll+断网,才可绕过Win11硬件检测。

有的人修改4项注册表,即可绕过Win11硬件检测。

有的人修改5项注册表,才可绕过Win11硬件检测。

有的人修改4项注册表+断网,才可绕过Win11硬件检测。

有的人删除appraiserres.dll+修改5项注册表,才可以绕过Win11硬件检测。

有的人删除appraiserres.dll+修改5项注册表,还不行,还必须断网,才可以绕过Win11硬件检测。

为什么会出现这么多不同情况呢?主要原因在于:大家的电脑配置情况不同,升级安装的操作方法不同。作为写程序来说,算法应该尽量适配所有(或绝大部分)情况。

技术三要素

我经过摸索以及实践检验,目前来看技术三要素修改5项注册表+删appraiserres.dll+断网,只要满足了这三个条件,无论在什么环境下,无论怎么操作,目前还没有遇到不能绕过Win11硬件检测的情况。

详解如下:

技术要素一:修改5项注册表

reg add "HKLM\SYSTEM\Setup\LabConfig" /v "BypassTPMCheck" /t REG_DWORD /d "1" /f
reg add "HKLM\SYSTEM\Setup\LabConfig" /v "BypassSecureBootCheck" /t REG_DWORD /d "1" /f
reg add "HKLM\SYSTEM\Setup\LabConfig" /v "BypassRAMCheck" /t REG_DWORD /d "1" /f
reg add "HKLM\SYSTEM\Setup\LabConfig" /v "BypassStorageCheck" /t REG_DWORD /d "1" /f
reg add "HKLM\SYSTEM\Setup\MoSetup" /v "AllowUpgradesWithUnsupportedTPMOrCPU" /t REG_DWORD /d "1" /f

注释1:
BypassTPMCheck是绕过TPM检测;
BypassSecureBootCheck是绕过安全启动检测;
BypassRAMCheck是绕过内存检测;
BypassStorageCheck是绕过硬盘检测;
AllowUpgradesWithUnsupportedTPMOrCPU,这一条是微软官方发布的解决方案。主要是绕过CPU检测。且这一项只能绕过TPM2.0,不能绕过TPM1.2(最低要求),也就是说没有TPM模块的来说,绕不过去。

 

技术要素二:删除(或替换/重命名)appraiserres.dll

1、ISO镜像中,存在于\sources\appraiserres.dll,当使用镜像安装系统时,在双击setup.exe之前,删除(或替换或改名)它。

2、当前系统中,存在于C:\$WINDOWS.~BT\Sources\appraiserres.dll,在线升级安装时,盯住这个文件,发现了就删除它,可保证正常升级。

注释:存在这个文件也会造成硬件检测时提示不满足要求,处理方案是删除它们。也可以使用Win10(1703)版本中的同名文件替换或直接重命名。

技术要素三:断网

之所以断网,是因为动态更新时,还会自动下载appraiserres.dll,所以有时你以为删了它,实际上等于没删除。然而断了网,一切都好了~

实践操作

通过上面的技术三要素介绍,以后无论是哪种操作方法,时刻想到这些条件就可保证顺利升级/安装Win11。

套路来了:

1、不管在什么系统中操作,先添加这5个注册表再说

2、不管升级还是全新安装,看到appraiserres.dll就删除

3、除了在线升级外,一律断网

再举一个栗子:

把如下代码保存为批处理“start_setup.bat”,并放到ISO的根目录下+断网!!!以管理员身份运行。只要代码执行成功,绕过硬件检测的成功率目前是100%。(无论是在PE下,还是在Windows下)。

这几行代码加上手动断网,其实就是干了上面的三件事

@echo off
title 安装Win11绕过硬件检测By知彼而知己
echo.
reg query HKU\S-1-5-19 1>nul 2>nul || goto :Admin
echo 正在启动......
del /f /q "%~dp0sources\appraiserres.dll"
reg add "HKLM\SYSTEM\Setup\LabConfig" /v "BypassTPMCheck" /t REG_DWORD /d "1" /f
reg add "HKLM\SYSTEM\Setup\LabConfig" /v "BypassSecureBootCheck" /t REG_DWORD /d "1" /f
reg add "HKLM\SYSTEM\Setup\LabConfig" /v "BypassRAMCheck" /t REG_DWORD /d "1" /f
reg add "HKLM\SYSTEM\Setup\LabConfig" /v "BypassStorageCheck" /t REG_DWORD /d "1" /f
reg add "HKLM\SYSTEM\Setup\MoSetup" /v "AllowUpgradesWithUnsupportedTPMOrCPU" /t REG_DWORD /d "1" /f
reg query "HKLM\Software\Microsoft\Windows NT\CurrentVersion\WinPE" || (reg query "HKLM\SYSTEM\CurrentControlSet\Control" /v SystemStartOptions | find /i "MINNT" || (start "11" "%~dp0setup.exe" &exit))
start "11" "%~dp0sources\setup.exe"
exit

:Admin
echo 请以管理员身份运行
echo.
pause >nul

最后的讨论

回到本文开头的诸多不同情况,归根结底在于双击“setup.exe”出现的此类问题居多,如果不按照上述三要素操作,有时也能成功:

1、Windows下,双击iso\setup.exe时,务必删除appraiserres.dll(或替换或改名)。

2、Windows下,双击iso\source\setup.exe时,务必保证已修改5项注册表。

3、WinPE下,无论双击哪个setup.exe,务必保证已修改5项注册表。

至于iso\setup.exe和iso\source\setup.exe的区别,我专门在《Win11升级攻略》中介绍过:

1、Windows下双击ISO根目录下的setup.exe为升级安装,可以保留文件、设置等一系列当前系统的信息;2、Windows下双击ISO\sources目录下的setup.exe,既可以升级安装、也可以全新安装(自定义安装)。但是全新安装的缺点是,不能格式化C盘,会生成一个windows.old文件夹(比升级安装生成的这个文件夹体积要大很多)。除此之外,与U盘/光盘启动格式化全新安装没有区别。事后虽然可以把这个文件夹清理掉,只是洁癖患者可能觉得它脏了图片。其实这也算是一种既方便又好用的方法,需要了解一下,说不定哪天就用到了。

来源:   https://mp.weixin.qq.com/s/0IWGgl8hzLy0MmcEQpYJgw

未经允许不得转载:Blog.XiaoMing.Xyz » 完美绕过Win11硬件限制的技术要素
分享到: 更多 (0)

评论 抢沙发

  • 昵称 (必填)
  • 邮箱 (必填)
  • 网址